DTC-SQL-FAQ

CREATE FUNCTION dbo.Age
    (
      @StartDate DATETIME,
      @EndDate DATETIME
    )
RETURNS @age TABLE
    (
      years INT,
      months INT,
      days INT
    )
AS BEGIN  
    DECLARE @SIGN SMALLINT  
    DECLARE @datumalt DATETIME  
    DECLARE @datumneu DATETIME  
 
    IF @StartDate > @EndDate 
        BEGIN  
            SET @datumalt = @EndDate  
            SET @datumneu = @StartDate  
            SET @SIGN = -1  
        END  
    ELSE 
        BEGIN  
            SET @datumalt = @StartDate  
            SET @datumneu = @EndDate  
            SET @SIGN = 1  
        END  
 
    INSERT  INTO @age
            SELECT  CASE WHEN DAY(@datumalt) <= DAY(@datumneu)
                         THEN ( DATEDIFF(MONTH, @datumalt, @datumneu) / 12 )
                              * @SIGN
                         ELSE ( ( DATEDIFF(MONTH, @datumalt, @datumneu) - 1 )
                                / 12 ) * @SIGN
                    END,
                    CASE WHEN DAY(@datumalt) <= DAY(@datumneu)
                         THEN ( DATEDIFF(MONTH, @datumalt, @datumneu) % 12 )
                              * @SIGN
                         ELSE ( ( DATEDIFF(MONTH, @datumalt, @datumneu) - 1 )
                                % 12 ) * @SIGN
                    END,
                    CASE WHEN DAY(@datumalt) <= DAY(@datumneu)
                         THEN ( DAY(@datumneu) - DAY(@datumalt) ) * @SIGN
                         ELSE ( DATEDIFF(DAY,
                                         DATEADD(MONTH,
                                                 DATEDIFF(MONTH, @datumalt,
                                                          @datumneu) - 1,
                                                 @datumalt), @datumneu) )
                              * @SIGN
                    END  
    RETURN  
   END